I thought of putting a tutorial on how I created a simple chat application which is possible using flash player 10 onwards. Believe me this does not require a costly media server to implement. Its very fast and communicates using Peer 2 Peer mechanism(P2P).

So what actually happens here is two flash player’s can communicate with each other directly. As shown in the picture below:

The above scenario would possibly erupt a volcano of ideas which can be possible with this kind of communication. Well I have already got many ideas related to developing an instant messenger or a multi player game etc. etc..

So I would just like to show how I developed a simple chat application which didn’t even took 15 minutes of my time to develop. So instead of wasting time reading this lets get into developing a chat application on the above technology.

Requirements:

• Adobe Stratus developer key
  For details about Adobe Stratus http://labs.adobe.com/technologies/stratus/
  For developer Key https://www.adobe.com/cfusion/entitlement/index.cfm?e=stratus

• Flex SDK 3.2 or higher http://www.adobe.com/support/flex/downloads_updaters.html
• Flash Player 10

Before we continue I would like you to see what we are going to develop

You can find two instances of flash player below which from now onwards will be referred as FP 1 and 2 respectively. Enter the nick name [Textfield] in FP 1 and 2. My id will be a long string of alpha numeric characters. Copy and paste the my id of FP1 to FP2 send message to id text field. In the same way copy the my id of FP2 and paste it in the send message to id text field of FP 1. Press connect buttons in both FP1 and FP2. After few milliseconds the controls like message box, send textfield and send button will get enabled.

Now type some message in FP1  and press send, thats it messages will get transfered from FP1 to FP2.  mmm.. a text chat application starts working.

FP 1

FP 2

Now lets see what happens inside. The code is well commented to make things clear

<?xml version="1.0" encoding="utf-8"?>
<mx:Application xmlns:mx="http://www.adobe.com/2006/mxml" layout="absolute" creationComplete="init()">

      <mx:Script>
            <![CDATA[
            	import mx.controls.Alert;
                  //The url to adobe stratus
                  private var mRtmfp_url:String="rtmfp://stratus.adobe.com";
                  private var mDeveloperKey:String=YOUR DEVELOPER KEY GOES HERE;
                  // Object of Net connection
                  private var mNetConnection:NetConnection;
                  //The client id generated by stratus is store in the bindable variable mId
                  [Bindable]
                  private var mId:String;
                  //The net stream for sending data
                  private var mSendStream:NetStream;
                  // The net stream for receiving data
                  private var mRecStream:NetStream;

                  public function init():void
                  {

                        connect_btn.addEventListener(MouseEvent.MOUSE_UP, connectPeer);
                        send_btn.addEventListener(MouseEvent.MOUSE_UP, sendMessage);

                        mNetConnection = new NetConnection();
                        mNetConnection.addEventListener(NetStatusEvent.NET_STATUS, netConnectionHandler);
                        mNetConnection.connect(mRtmfp_url+"/"+mDeveloperKey);
                  }

                  private function netConnectionHandler(vEvent:NetStatusEvent):void
                  {
                       if(vEvent.info.code=="NetConnection.Connect.Success")
                       {
                       		mId=mNetConnection.nearID;

                       		mSendStream=new NetStream(mNetConnection, NetStream.DIRECT_CONNECTIONS);
                       		mSendStream.addEventListener(NetStatusEvent.NET_STATUS,onSendStreamHandler);
          					mSendStream.publish("mystream");
                       }

                  }

                  private function sendMessage(vEvent:MouseEvent):void
                  {
                  	if(send_message_txt.text=="")
                  	{

                  	}
                  	else
                  	{
                  		var message_to_send:String="<b>"+myname_txt.text+": </b>"+send_message_txt.text+"<br/>";
                  		mSendStream.send("reciveMessage", message_to_send);
                  		message_box_txt.htmlText+=message_to_send;
                  		send_message_txt.text="";
                  	}
                  }

                  public function reciveMessage(vMessage:String):void
                  {
                  	message_box_txt.htmlText+=vMessage;
                  }

                  private function connectPeer(vEvent:MouseEvent):void
                  {
                  	if(send_id_txt.text=="")
                  	{
                  		Alert.show("Peer id cannot be empty!");
                  	}
                  	else
                  	{
                  		mRecStream = new NetStream(mNetConnection,send_id_txt.text);
					    mRecStream.addEventListener(NetStatusEvent.NET_STATUS,onReceiveStreamHandler);
					    mRecStream.play("mystream");
					    mRecStream.client = this;
                  	}

                  }

                  private function onSendStreamHandler(vEvent:NetStatusEvent):void
                  {

                  }

                  private function onReceiveStreamHandler(vEvent:NetStatusEvent):void
                  {
                  	if(vEvent.info.code=="NetStream.Play.Start")
                  	{
                  		message_box_txt.enabled=true;
                  		message_box_txt.alpha=1;

                  		send_message_txt.enabled=true;
                  		send_message_txt.alpha=1;

                  		send_btn.enabled=true;
                  		send_btn.alpha=1;
                  	}
                  }

            ]]>
      </mx:Script>

    <mx:VBox paddingLeft="10" paddingTop="10" paddingRight="10" paddingBottom="10" width="100%" height="100%">
    	<mx:Label text="Stratus demo text chat application"/>
    	<mx:HBox width="100%">
    		<mx:Label text="Nick name:"/>
    		<mx:TextInput id="myname_txt" width="50%" />
    	</mx:HBox>
    	<mx:HBox width="100%">
    		<mx:Label text="My id is"/>
    		<mx:Label text="{mId}" selectable="true"/>
    	</mx:HBox>
    	<mx:HBox width="100%">
    		<mx:Label text="Send message to id"/>
    		<mx:TextInput id="send_id_txt" width="70%" />
    		<mx:Button id="connect_btn" label="Connect" />
    	</mx:HBox>
    	<mx:TextArea id="message_box_txt" enabled="false" alpha="0.5" width="100%" height="60%"/>
    	<mx:HBox width="100%">
    		<mx:TextInput width="70%" enabled="false" alpha="0.5" id="send_message_txt" />
    		<mx:Button label="send" enabled="false" alpha="0.5"  id="send_btn"/>
    	</mx:HBox>
    </mx:VBox>

</mx:Application>